make process-compose-flake usable without flake-parts

CHANGELOG.md

@@ -6,6 +6,7 @@
     - ~~#18: Add `testScript` option for adding flake checks based on nixosTest library.~~
     - #39: Allow `test` process to act as a test, which then gets run as part of flake checks.
     - #55: Add `lib` flake output - library of useful functions
+        - #80: Add `evalModules`, to use process-compose-flake without flake-parts
     - New options
       - #52: Add `is_foreground` option
       - ~~#54: Add `apiServer` option to control REST API server~~

example/flake.nix

@@ -76,6 +76,22 @@
               };
             };
           };
+
+        # nix run .#ponysay up to start the process
+        packages.ponysay = (import inputs.process-compose-flake.lib { inherit pkgs; }).makeProcessCompose {
+          modules = [{
+            settings = {
+              processes = {
+                ponysay.command = ''
+                  while true; do
+                    ${lib.getExe pkgs.ponysay} "Hi!"
+                    sleep 2
+                  done
+                '';
+              };
+            };
+          }];
+        };
       };
     };
 }

nix/lib.nix

@@ -1,4 +1,4 @@
-{ lib, ... }:
+{ pkgs, lib ? pkgs.lib, ... }:
 
 rec {
   # Lookup an environment in process-compose environment list
@@ -31,4 +31,23 @@ rec {
   types = {
     command = import ./process-compose/setting/command.nix { inherit lib; };
   };
+
+  # Run the process-compose-module stand-alone, without flake-parts
+  # - modules: list of modules that set process-compose-flake options
+  # - name: name of the module, you typically don't need to set this
+  # Returns the full result of the module evaluation
+  evalModules = { name ? "process-compose", modules }: (lib.evalModules {
+    specialArgs = {
+      inherit name pkgs;
+    };
+    modules = [
+      ./process-compose
+    ] ++ modules;
+  });
+
+  # Same as evalModules, but returns the process-compose process directly
+  makeProcessCompose = { name ? "process-compose", modules }: (evalModules {
+    inherit name;
+    modules = modules;
+  }).config.outputs.package;
 }