build.gradle

plugins {
    id 'java'
    id "com.google.protobuf" version "0.8.12"
    id 'idea'
}

group 'org.example'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
}

dependencies {
    compile group: 'com.google.protobuf', name: 'protobuf-java', version: '3.9.0'

    // Ref: https://github.com/grpc/grpc-java/blob/master/README.md
    implementation 'io.grpc:grpc-netty-shaded:1.30.2'
    implementation 'io.grpc:grpc-protobuf:1.30.2'
    implementation 'io.grpc:grpc-stub:1.30.2'
    compileOnly 'org.apache.tomcat:annotations-api:6.0.53' // necessary for Java 9+

    testCompile group: 'junit', name: 'junit', version: '4.12'
}

idea {
    module {
        generatedSourceDirs = [ file("src/main/generated") ]

        sourceDirs += file("src/main/java")
        sourceDirs += file("src/main/generated")
    }
}

clean {
    delete 'src/main/generated'
}

protobuf {
    protoc {
        // Download from repositories : https://mvnrepository.com/artifact/com.google.protobuf/protoc
        artifact = 'com.google.protobuf:protoc:3.12.0'
        generatedFilesBaseDir = "$projectDir/src/main/generated"
    }
    plugins {
        grpc {
            artifact = 'io.grpc:protoc-gen-grpc-java:1.30.2'
        }
    }
    generateProtoTasks {
        all()*.plugins {
            grpc {}
        }
    }
}