build.gradle

plugins {
	id("java")
	id("maven-publish")
	id("signing")
	id("net.auoeke.gronk").version("3.+")
}

version("0.6.0")
description("Properties with structure and types")
javaVersion(17)

allprojects {
	plugins.apply("java")
	group("net.auoeke")

	jar {
		from("LICENSE.md") {
			into("META-INF")
		}
	}
}

gronk {
	uncheck()
}

sourceSets {
	test {
		resources.srcDir("test")
	}
}

dependencies {
	implementation("net.auoeke:reflect")

	testImplementation("org.junit.jupiter:junit-jupiter-api")
	testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine")
}

compileJava {
	// "package %s does not exist"
	// "cannot find symbol class %s"
	// Somewhy clean fixes these errors.
	dependsOn(clean)
}

compileTestJava {
	sourceCompatibility = targetCompatibility = 19
	options.compilerArgs << "--enable-preview"
}

test {
	useJUnitPlatform()
}

java {
	withJavadocJar()
}

publishing {
	repositories {
		maven(findProperty("maven.repository")) {
			username(findProperty("maven.username"))
			password(findProperty("maven.password"))
		}
	}

	publications.withType(MavenPublication) {
		pom {
			url.set("https://github.com/auoeke/structured-properties")

			licenses {
				license {
					url.set("https://raw.githubusercontent.com/auoeke/gronk/master/LICENSE")
				}
			}

			developers {
				developer {
					id.set("auoeke")
					email.set("me@auoeke.net")
				}
			}

			scm {
				connection.set("scm:git:git://github.com/auoeke/structured-properties.git")
				developerConnection.set("scm:git:git://github.com/auoeke/structured-properties.git")
				url.set("https://github.com/auoeke/structured-properties/tree/master")
			}
		}
	}

}