build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.bmuschko:gradle-nexus-plugin:2.3.1'
    }
}

apply plugin: 'com.bmuschko.nexus'
apply plugin: 'java'

repositories {
    jcenter()
}
dependencies {
    testImplementation 'junit:junit:4.12'
}


archivesBaseName = 'JavaRDS'
group = "com.nexteraanalytics.r"
version = "0.2-SNAPSHOT"

modifyPom {
    project {
        name 'JavaRDS'
        description 'Create R-style RDS data from Java'
        url 'https://github.com/focusenergy/JavaRDS'
        inceptionYear '2019'
        scm {
            url 'https://github.com/focusenergy/JavaRDS'
            connection 'scm:https://github.com/focusenergy/JavaRDS.git'
            developerConnection 'scm:git@github.com:focusenergy/JavaRDS.git'
        }
        licenses {
            license {
                name 'The MIT License'
                url 'https://opensource.org/licenses/MIT'
                distribution 'repo'
            }
        }
        developers {
            developer {
                id 'kenahoo'
                name 'Ken Williams'
                email 'ken.williams@nexteraanalytics.com'
            }
        }
    }
}

extraArchive {
    sources = true
    tests = true
    javadoc = true
}

nexus {
    sign = true
    repositoryUrl = 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
    snapshotRepositoryUrl = 'https://oss.sonatype.org/content/repositories/snapshots/'
}

javadoc {
    // Let us omit argument docs, at least for now
    options.addBooleanOption('Xdoclint:none', true)
}