build.gradle

buildscript {
    repositories {
        mavenCentral()
        google()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:8.1.4'
        classpath 'org.jetbrains.kotlin:kotlin-gradle-plugin:1.9.0'
    }
}

apply plugin: 'com.android.library'
apply plugin: 'maven-publish'
apply plugin: 'signing'


group = GROUP
version = VERSION_NAME

android {
    namespace "com.mixpanel.android"
    compileSdk 34
    buildToolsVersion = "34.0.0"
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }

    lintOptions {
        abortOnError false
    }

    defaultConfig {
        minSdk 21
        targetSdk 34
        multiDexEnabled true
        android.buildFeatures.buildConfig true
        testApplicationId "com.mixpanel.android.mpmetrics"
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles 'proguard.txt'

        buildConfigField "String", "MIXPANEL_VERSION", "\"${version}\""

        lintOptions {
            abortOnError true
            warningsAsErrors false
            disable "UnusedResources"
            textOutput "stdout"
            textReport true
        }

        testOptions {
            execution 'ANDROIDX_TEST_ORCHESTRATOR'
        }
    }
    buildTypes {
        debug{
            minifyEnabled false
            debuggable true
            testCoverageEnabled true
        }
        release {
            minifyEnabled false
        }
    }
}

allprojects {
    gradle.projectsEvaluated {
        tasks.withType(JavaCompile) {
            options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
        }
    }
    repositories {
        mavenCentral()
        google()
    }
}

configurations.all {
    resolutionStrategy {
        force "org.jetbrains.kotlin:kotlin-stdlib-jdk7:1.8.22"
        force "org.jetbrains.kotlin:kotlin-stdlib-jdk8:1.8.22"
    }
}

dependencies {
    implementation "androidx.annotation:annotation:1.8.2"
    implementation 'androidx.core:core:1.13.1'
    // AndroidJUnitRunner and JUnit Rules
    testImplementation 'junit:junit:4.13.2'
    androidTestImplementation 'androidx.test:core:1.6.1'
    androidTestImplementation 'androidx.test:runner:1.6.2'
    androidTestImplementation 'androidx.test:rules:1.6.1'
    androidTestImplementation 'androidx.test.ext:junit:1.2.1'
    androidTestImplementation 'androidx.test.ext:truth:1.6.0'
    androidTestImplementation "org.mockito:mockito-android:2.25.1"
    androidTestUtil 'androidx.test:orchestrator:1.5.0'
    testImplementation "org.mockito:mockito-core:2.25.1"
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.6.1'
}

apply from: rootProject.file('maven.gradle')