build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'org.jfrog.buildinfo:build-info-extractor-gradle:4.3.0'
        classpath 'nu.studer:gradle-plugindev-plugin:1.0.4'
        classpath 'org.codehaus.groovy:groovy-backports-compat23:2.4.6'
        classpath 'net.researchgate:gradle-release:2.3.5'
    }
}

apply plugin: 'groovy'
apply plugin: 'idea'
apply plugin: 'nu.studer.plugindev'
apply plugin: 'com.jfrog.artifactory'
apply plugin: 'net.researchgate.release'

group='net.researchgate'

dependencies {
    testCompile("org.spockframework:spock-core:$spockVersion") { exclude group: 'org.codehaus.groovy' }
    testCompile "junit:junit:$junitVersion"
    testCompile "org.eclipse.jgit:org.eclipse.jgit:$jgitVersion"
    testCompile "cglib:cglib-nodep:$cglibVersion"
}

plugindev {
    pluginImplementationClass 'net.researchgate.release.ReleasePlugin'
    pluginDescription 'gradle-release is a plugin for providing a Maven-like release process to project using Gradle.'
    pluginLicenses 'MIT'
    pluginTags 'gradle', 'plugin', 'release'
    authorId 'danez'
    authorName 'Daniel Tschinder'
    authorEmail 'daniel.tschinder@researchgate.net'
    projectUrl 'https://github.com/researchgate/gradle-release'
    projectInceptionYear '2011'
    done() // do not omit this
}

release {
    git {
        requireBranch = '(master|\\d+\\.\\d+)'
    }
}

bintray {
    user = project.hasProperty('bintrayUser') ? bintrayUser : ''
    key = project.hasProperty('bintrayApiKey') ? bintrayApiKey : ''
    pkg {
        repo = 'gradle-plugins'
        userOrg = 'researchgate'
        version {
            gpg {
                sign = true
                passphrase = project.hasProperty('bintrayGpgPassphrase') ? bintrayGpgPassphrase : ''
            }
            mavenCentralSync {
                user = project.hasProperty('sonatypeUser') ? sonatypeUser : ''
                password = project.hasProperty('sonatypePassword') ? sonatypePassword : ''
            }
        }
    }
    publish = true
}

artifactory {
    contextUrl = 'https://oss.jfrog.org'
    publish {
        repository {
            repoKey = 'oss-snapshot-local' //The Artifactory repository key to publish to
            username = project.hasProperty('bintrayUser') ? bintrayUser : ''
            password = project.hasProperty('bintrayApiKey') ? bintrayApiKey : ''
        }
        defaults {
            publications 'plugin' // That is how it is named in plugindev plugin
            properties = ['bintray.repo': 'gradle-plugins', 'bintray.package': 'gradle-release', 'bintray.version': version.toString()]
        }
    }
    resolve {
        repoKey = 'jcenter'
    }
}

afterReleaseBuild.dependsOn bintrayUpload

wrapper.gradleVersion = '1.12'