build.gradle

buildscript {
    repositories {
        mavenCentral()
        jcenter()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath 'ch.raffael.markdown-doclet:markdown-doclet:1.4'
    }
}

plugins {
    id 'groovy'
    id 'java-library'
    id 'jacoco'
    id 'nebula.maven-publish' version '9.5.0'
    id 'nebula.javadoc-jar' version '9.5.0'
    id 'nebula.source-jar' version '9.5.0'
    id 'nebula.release' version '9.2.0'
    id 'nebula.contacts' version '5.0.0'
    id 'nebula.info' version '5.0.0'
    id "com.jfrog.bintray" version "1.8.4"
    id "com.github.hierynomus.license" version "0.15.0"
    id 'org.ajoberstar.git-publish' version '2.0.0'
}

apply plugin: 'ch.raffael.markdown-doclet'

description 'Common library with helpers for the KlumSuite'
group 'com.blackbuild.klum.common'

sourceCompatibility = JavaVersion.VERSION_1_7
targetCompatibility = JavaVersion.VERSION_1_7

repositories {
    jcenter()
}

jacoco {
    toolVersion = "0.8.2"
}

configurations.testCompileOnly.extendsFrom configurations.compileOnly

dependencies {
    compile "org.codehaus.groovy:groovy-all:2.4.12"
    compile "com.intellij:openapi:7.0.3"
    testCompile("org.spockframework:spock-core:1.1-groovy-2.4")
    testRuntime "net.bytebuddy:byte-buddy:1.7.5"
    testRuntime "org.objenesis:objenesis:2.6"
}


bintray {
    user = findProperty('bintrayUser')
    key = findProperty('bintrayApiKey')

    publications = ['nebula']
    dryRun = false
    publish = true
    pkg {
        repo = 'klum-dsl'
        userOrg = 'klum-dsl'
        name = project.name
        desc = project.description
        websiteUrl = 'https://github.com/klum-dsl/klum-common'
        issueTrackerUrl = 'https://github.com/klum-dsl/klum-common/issues'
        vcsUrl = 'https://github.com/klum-dsl/klum-common.git'
        licenses = ['MIT']
        labels = ['groovy', 'ast']
        publicDownloadNumbers = true
        attributes = [:]
        version {
            name = project.version
            vcsTag = project.version
            attributes = [:]
            gpg {
                sign = true
                passphrase = findProperty("signing.password")
            }
            mavenCentralSync {
                sync = !version.toString().contains(".dev+")
                user = findProperty("nexusUsername")
                password = findProperty("nexusPassword")
            }
        }
    }
}

contacts {
    'stephan@blackbuild.com' {
        moniker 'Stephan Pauxberger'
        github 'pauxus'
    }
}

publishing {
    publications {
        nebula(MavenPublication) {
            pom.withXml {
                def p = asNode()
                p.dependencies.dependency.find { it.artifactId.text() == "groovy-all" }.appendNode('optional', true)
                p.dependencies.dependency.find { it.artifactId.text() == "openapi" }.appendNode('optional', true)
                p.name.first().setValue('KlumCommon')
                p.appendNode('licenses').appendNode('license').
                        appendNode('name', 'The MIT License (MIT)').parent().
                        appendNode('url', 'http://opensource.org/licenses/MIT')
            }
        }
    }
}

tasks.release.dependsOn 'build'
tasks.postRelease.dependsOn 'publish'