build.gradle

repositories {
	mavenCentral()
}

buildscript {
	repositories {
		mavenCentral()
	}
	dependencies {
		classpath("org.springframework.boot:spring-boot-gradle-plugin:1.5.2.RELEASE")
		classpath("se.transmode.gradle:gradle-docker:1.2")
	}
}

apply plugin: 'java'
apply plugin: 'org.springframework.boot'
apply plugin: 'war'
apply plugin: se.transmode.gradle.plugins.docker.DockerPlugin


war {
	baseName = 'app'
	version = '1.0'
}

dependencies {
	compile group: 'org.springframework.boot', name: 'spring-boot-starter-web'
	compile group: 'org.springframework.boot', name: 'spring-boot-starter-security'
	compile group: 'org.springframework.boot', name: 'spring-boot-starter-thymeleaf'
	compile group: 'com.h2database', name:'h2', version: '1.4.194'
	compile group: 'org.json', name: 'json', version: '20160212'

	providedRuntime("org.springframework.boot:spring-boot-starter-tomcat")

	testCompile "org.springframework.boot:spring-boot-starter-test"
}

bootRun {
	addResources = false
	if (rootProject.hasProperty('debug')) {
		jvmArgs += ['-Xdebug', '-Xrunjdwp:server=y,transport=dt_socket,address=8000,suspend=n']
	}
}

task docker(type: Docker) {
	dependsOn bootRepackage

	baseImage = 'library/openjdk:8u131-jdk'
	tag = 'bmrobin/phish-weather-api'
	tagVersion = 'latest'

	addFile project.war.archivePath, '/data/app.war'
	exposePort 8080
	defaultCommand = [ '/usr/bin/java', '-jar', '/data/app.war' ]
}