build.gradle

// Global gradle configuration. This configuration will be used for all sub-projects.
apply from: './configuration.gradle'
apply from: './repositories.gradle'
apply from: './dependencies.gradle'

/**
 * Global build script configuration ===============================================================
 */
buildscript {
    repositories {
        google()
        jcenter()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:3.6.1'
        classpath 'com.vanniktech:gradle-android-junit-jacoco-plugin:0.15.0'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.4'
    }
}

/**
 * All projects global configuration ===============================================================
 */
allprojects {
    repositories {
        google()
        jcenter()
        maven { url repos.bintray.universum.studios.android }
        mavenLocal()
        maven { url repos.project.artifacts }
    }

    // Disable pre-dexing of libraries when running builds in CI environment.
    if (config.ci.EXECUTING == true) {
        project.plugins.whenPluginAdded { plugin ->
            if (plugin.class.name == "com.android.build.gradle.AppPlugin") {
                logger.quiet("Disabled pre-dexing for module :${project.name}")
                project.android.dexOptions.preDexLibraries = false
            } else if (plugin.class.name == "com.android.build.gradle.LibraryPlugin") {
                logger.quiet("Disabled pre-dexing for library module :${project.name}")
                project.android.dexOptions.preDexLibraries = false
            }
        }
    }
}

/**
 * All projects global tasks =======================================================================
 */

/**
 * Task that cleans build directory of the root project.
 */
task clean(type: Delete) {
    delete rootProject.buildDir
}

/**
 * Task that assembles release variant of all library modules.
 */
task assembleLibrary() {
    group 'build'
    description 'Assembles release variant of all library modules.'
    subprojects.findAll { if (it.name.startsWith("library")) dependsOn ":${it.name}:assembleRelease" }
}

/**
 * Task that deploys (uploads) the primary library module into Maven local repository.
 */
task deployToMavenLocal(dependsOn: ':library:publishToMavenLocal') {
    group 'deploy'
    description 'Deploys primary artifact of the library to the local Maven repository.'
}

/**
 * Task that deploys (uploads) all library modules (except groups) into Maven local repository.
 */
task deployModulesToMavenLocal() {
    group 'deploy'
    description 'Deploys artifacts for all library modules (except groups) into Maven local repository.'
    subprojects.findAll { if (it.name.startsWith("library-") && !it.name.endsWith('_group')) dependsOn ":${it.name}:publishToMavenLocal" }
}

/**
 * Task that deploys (uploads) all library module groups into Maven local repository.
 */
task deployGroupsToMavenLocal() {
    group 'deploy'
    description 'Deploys artifacts for all library module groups into Maven local repository.'
    subprojects.findAll { if (it.name.startsWith("library-") && it.name.endsWith('_group')) dependsOn ":${it.name}:publishToMavenLocal" }
}

/**
 * Task that deploys (uploads) the primary library module up to the Bintray repository.
 */
task deployToBintray(dependsOn: ':library:bintrayUpload') {
    group 'deploy'
    description 'Deploys primary artifact of the library up to the Bintray repository.'
}

/**
 * Task that deploys (uploads) all library modules (except groups) up to the Bintray repository.
 */
task deployModulesToBintray() {
    group 'deploy'
    description 'Deploys artifacts for all library modules (except groups) up to the Bintray repository.'
    subprojects.findAll { if (it.name.startsWith("library-") && !it.name.endsWith('_group')) dependsOn ":${it.name}:bintrayUpload" }
}

/**
 * Task that deploys (uploads) all library module groups up to the Bintray repository.
 */
task deployGroupsToBintray() {
    group 'deploy'
    description 'Deploys artifacts for all library module groups up to the Bintray repository.'
    subprojects.findAll { if (it.name.startsWith("library-") && it.name.endsWith('_group')) dependsOn ":${it.name}:bintrayUpload" }
}

/**
 * Task that updates library artifacts directory.
 */
task updateArtifacts() {
    subprojects.findAll { if (it.name.startsWith("library")) dependsOn ":${it.name}:updateArtifacts" }
    doLast {
        if (file(repos.project.artifacts).exists()) {
            exec {
                commandLine 'git', 'add', repos.project.artifacts, '-A'
            }
        }
    }
}