.gdbinit

#  .gdbinit
#
#  Copyright (c) 2017-2023, Joshua Riek
#
#  This program is free software: you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation, either version 3 of the License, or
#  (at your option) any later version.
#
#  This program is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#
#  You should have received a copy of the GNU General Public License
#  along with this program.  If not, see <http://www.gnu.org/licenses/>.
#

set tdesc filename target.xml

target remote localhost:1234

set confirm off
set verbose off
set prompt \033[31mgdb$ \033[0m

set output-radix 0d10
set input-radix 0d10

# These make gdb never pause in its output
set height 0
set width 0
set pagination off

# Intel syntax
set disassembly-flavor intel

# Real mode
set architecture i8086

set $SHOW_CONTEXT = 1

set $REAL_MODE = 1

# By default A20 is present
set $ADDRESS_MASK = 0x1FFFFF

# nb of instructions to display
set $CODE_SIZE = 10

define enable-a20
    set $ADDRESS_MASK = 0x1FFFFF
end
define disable-a20
    set $ADDRESS_MASK = 0x0FFFFF
end

# get current register values
define compute_regs
    set $rax = ((unsigned long)$eax & 0xFFFF)
    set $rbx = ((unsigned long)$ebx & 0xFFFF)
    set $rcx = ((unsigned long)$ecx & 0xFFFF)
    set $rdx = ((unsigned long)$edx & 0xFFFF)
    set $rsi = ((unsigned long)$esi & 0xFFFF)
    set $rdi = ((unsigned long)$edi & 0xFFFF)
    set $rbp = ((unsigned long)$ebp & 0xFFFF)
    set $rsp = ((unsigned long)$esp & 0xFFFF)
    set $rcs = ((unsigned long)$cs & 0xFFFF)
    set $rds = ((unsigned long)$ds & 0xFFFF)
    set $res = ((unsigned long)$es & 0xFFFF)
    set $rss = ((unsigned long)$ss & 0xFFFF)
    set $rip = ((((unsigned long)$cs & 0xFFFF) << 4) + ((unsigned long)$eip & 0xFFFF)) & $ADDRESS_MASK
    set $r_ss_sp = ((((unsigned long)$ss & 0xFFFF) << 4) + ((unsigned long)$esp & 0xFFFF)) & $ADDRESS_MASK
    set $r_ss_bp = ((((unsigned long)$ss & 0xFFFF) << 4) + ((unsigned long)$ebp & 0xFFFF)) & $ADDRESS_MASK
end

# print CPU registers
define print_regs
    printf " AX: 0x%04X BX: 0x%04X ", $rax, $rbx
    printf " CX: 0x%04X DX: 0x%04X\n", $rcx, $rdx
    printf " SI: 0x%04X DI: 0x%04X ", $rsi, $rdi
    printf " SP: 0x%04X BP: 0x%04X\n", $rsp, $rbp
    printf " CS: 0x%04X DS: 0x%04X ", $rcs, $rds
    printf " ES: 0x%04X SS: 0x%04X\n", $res, $rss
    printf "\n"
    printf " IP: 0x%04X EIP: 0x%08X\n", ((unsigned short)$eip & 0xFFFF), $eip
    printf " CS:IP: %04X:%04X (0x%05X)\n", $rcs, ((unsigned short)$eip & 0xFFFF), $rip
    printf " SS:SP: %04X:%04X (0x%05X)\n", $rss, $rsp, $r_ss_sp
    printf " SS:BP: %04X:%04X (0x%05X)\n", $rss, $rbp, $r_ss_bp
end

# print eflags registers
define print_eflags
    printf "\n OF <%d>  DF  <%d> IF  <%d> TF <%d>",\
          (($eflags >> 0xB) & 1), (($eflags >> 0xA) & 1), \
          (($eflags >> 9) & 1), (($eflags >> 8) & 1)
    printf "  SF <%d>  ZF <%d>  AF <%d>  PF   <%d>  CF <%d>\n",\
          (($eflags >> 7) & 1), (($eflags >> 6) & 1),\
          (($eflags >> 4) & 1), (($eflags >> 2) & 1), ($eflags & 1)
    printf " ID <%d>  VIP <%d> VIF <%d> AC <%d>",\
          (($eflags >> 0x15) & 1), (($eflags >> 0x14) & 1), \
          (($eflags >> 0x13) & 1), (($eflags >> 0x12) & 1)
    printf "  VM <%d>  RF <%d>  NT <%d>  IOPL <%d>\n",\
          (($eflags >> 0x11) & 1), (($eflags >> 0x10) & 1),\
          (($eflags >> 0xE) & 1), (($eflags >> 0xC) & 3)
end

# dump content of memory in words
# arg0 : addr
# arg1 : nb of words
define _dump_memw
    if $argc < 2
        printf "Arguments: address number_of_words\n"
    else
        set $_nb = $arg1
        set $_i = 0
        set $_addr = $arg0
        while ($_i < $_nb)
            printf "%04X ", *((unsigned short*)$_addr + $_i)
            set $_i++
        end
    end
end

# display data at given address
define print_data
    if ($argc > 0)
        set $wil = 4
        if ($argc > 2)
            set $wil = $arg2
        end

        set $seg = $arg0
        set $off = $arg1

        set $raddr = ($arg0 << 16) + $arg1
        set $maddr = ($arg0 << 4) + $arg1

        set $w = 16
        set $i = (int)0
        while ($i < $wil)
            printf "%04X %04X: ", ($seg), ($off+ $i * $w)
            set $j = (int)0
            while ($j < $w)
                printf "%02X ", *(unsigned char*)($maddr + $i * $w + $j)
                set $j++
            end
            printf " "
            set $j = (int)0
            while ($j < $w)
                set $c = *(unsigned char*)($maddr + $i * $w + $j)
                if ($c > 32) && ($c < 128)
                    printf "%c", $c
                else
                    printf "."
                end
                set $j++
            end
            printf "\n"
            set $i++
        end
    end
end

# print context window, i.e. regs, stack, ds:esi and disassemble cs:eip
define context
    printf "--------------------------------------------------------------------------------[stack]\n"
    _dump_memw $r_ss_sp 8
    printf "\n"
    set $_a = $r_ss_sp + 16
    _dump_memw $_a 8
    printf "\n"
    printf "--------------------------------------------------------------------------------[ds:si]\n"
    print_data $ds $rsi
    printf "--------------------------------------------------------------------------------[es:di]\n"
    print_data $es $rdi
    printf "--------------------------------------------------------------------------------[regs]\n"
    print_regs
    print_eflags
    printf "--------------------------------------------------------------------------------[code]\n"
    set $_code_size = $CODE_SIZE
    if ($_code_size > 0)
        x /i $rip
        set $_code_size--
    end
    while ($_code_size > 0)
        x /i
        set $_code_size--
    end
    printf "--------------------------------------------------------------------------------------\n"
end

define hook-stop
    compute_regs
    if ($SHOW_CONTEXT > 0)
        context
    end
end
document hook-stop
!!! FOR INTERNAL USE ONLY - DO NOT CALL !!!
end