build.gradle

apply plugin: 'java'
apply plugin: 'forge'

dependencies {
    compile ("appeng:appliedenergistics2:rv1-stable-1:dev") {
        exclude group: "net.industrial-craft", module: "industrialcraft-2"
        exclude group: "mcp.mobius.waila", module: "Waila"
        exclude group: "codechicken", module: "ForgeMultipart"
        exclude group: "codechicken", module: "CodeChickenCore"
        exclude group: "codechicken", module: "NotEnoughItems"
    }
}

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

configurations.all {
    resolutionStrategy.cacheDynamicVersionsFor 7200, 'hours'
}

// define the properties file
ext.configFile = file "build.properties"

configFile.withReader {
    // read config.  it shall from now on be referenced as simply config or as project.config
    def prop = new Properties()
    prop.load(it)
    project.ext.config = new ConfigSlurper().parse prop
}

sourceCompatibility = JavaVersion.VERSION_1_6
targetCompatibility = JavaVersion.VERSION_1_6

version="build-$System.env.DRONE_BUILD_NUMBER"
group = config.group
archivesBaseName = config.archivesBaseName

minecraft {
   version = config.minecraft_version + "-" + config.forge_version
    
	 replace "@version@", project.version
}

sourceSets {
    main {
        java {
            srcDir 'src/main/java/'
        }
        resources {
            srcDir 'src/main/resources/'
        }
    }
}

processResources
{
    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
        expand 'version': project.version, 'mcversion': config.minecraft_version
    }
}